home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Collection of Tools & Utilities
/
Collection of Tools and Utilities.iso
/
sound
/
zutil_f2.zip
/
ABR1.BAT
next >
Wrap
DOS Batch File
|
1993-01-31
|
2KB
|
88 lines
@ECHO OFF
rem --------------------------------
rem Anrufbeanworter mit Faxerkennung
rem --------------------------------
rem Standardkonfiguration : Modem an Port 1,
rem ZUTIL im Verzeichnis, von dem aus aufgerufen wird.
rem Lautstaerkepegel und Zeit fuer Silence-Erkennung festlegen
ZUTIL S /T3 "AT+VSD=16,30|" "OK"
:start
rem --- auf 1x Klingeln warten
ZUTIL W /R2 /T32000
IF ERRORLEVEL 1 goto anruf
goto start
rem ----------------------------------------------
:anruf
rem --- Abheben und Begruessung "... bitte sprechen sie nach dem Piep"
ZUTIL P HALLO.ZYX
rem --- Fehler ?
IF ERRORLEVEL 252 goto auflegen
rem --- Fax ?
IF ERRORLEVEL 251 goto data_anruf
rem --- anderer Fehler oder Abbruch durch Benutzer (alle E.l. >= 15) ?
IF ERRORLEVEL 15 goto auflegen
rem --- Fernabfrage (mit Tonwahl "4") ?
IF ERRORLEVEL 14 goto fernabfrage
rem --- Piep erzeugen, Nachricht aufnehmen, max. 30 Sekunden
ZUTIL R /F500 /D1 /T30 *.ZYX
rem --- Fehler ?
IF ERRORLEVEL 252 goto auflegen
rem --- evtl. doch ein Fax ?
IF ERRORLEVEL 251 goto data_anruf
rem --- Abbruch durch Benutzer
IF ERRORLEVEL 250 goto auflegen
rem --- Anrufer gibt nichts von sich (vielleicht doch Modem oder Fax ?)
IF ERRORLEVEL 249 goto data_anruf
rem --- BZT - zugelassene Anrufbeantworter muessen eine 'Absage' spielen
ZUTIL P /F500 /D1 ZEIT_AUS.ZYX
:auflegen
ZUTIL H
GOTO start
rem -------------------------------------------
:data_anruf
rem --- Fax/Datenmodus einschalten
ZUTIL S "AT#B1+FCLASS=6|" "OK" /T2
rem --- Fehler
IF ERRORLEVEL 2 GOTO auflegen
rem --- Versuchen, einen Connect herzustellen
ZUTIL S "ATA|" "FAX" "2400" "4800" "7200" "9600" "12000" "14400" "16800" "19200" "NO " /T45
rem --- "NO CARRIER" vom Modem, Timeout oder allg. Fehler...
IF ERRORLEVEL 10 GOTO auflegen
rem --- Modemconnect ?
IF ERRORLEVEL 2 GOTO mailbox_aufrufen
rem --- nein, also Faxconnect. (folgender Befehl gilt ab ZFAX2.2)
RCVFAX 2
GOTO start
:mailbox_aufrufen
rem --- z.B.
TELIX O SHOSTPLUS
GOTO start
:fernabfrage
rem --- alle aufgezeichneten nachrichten abspielen
ZUTIL P /F800 /D1 ZUTIL*.ZYX
GOTO auflegen