home *** CD-ROM | disk | FTP | other *** search
/ Collection of Tools & Utilities / Collection of Tools and Utilities.iso / sound / zutil_f2.zip / ABR1.BAT next >
DOS Batch File  |  1993-01-31  |  2KB  |  88 lines
  1. @ECHO OFF
  2. rem --------------------------------
  3. rem Anrufbeanworter mit Faxerkennung
  4. rem --------------------------------
  5.  
  6. rem Standardkonfiguration : Modem an Port 1,
  7. rem ZUTIL im Verzeichnis, von dem aus aufgerufen wird.
  8.  
  9. rem Lautstaerkepegel und Zeit fuer Silence-Erkennung festlegen
  10. ZUTIL S /T3 "AT+VSD=16,30|" "OK"
  11.  
  12. :start
  13.  
  14. rem --- auf 1x Klingeln warten
  15. ZUTIL W /R2 /T32000
  16.  
  17. IF ERRORLEVEL 1 goto anruf
  18. goto start
  19.  
  20. rem ----------------------------------------------
  21.  
  22. :anruf
  23.  
  24. rem --- Abheben und Begruessung "... bitte sprechen sie nach dem Piep"
  25. ZUTIL P HALLO.ZYX
  26.  
  27. rem --- Fehler ?
  28. IF ERRORLEVEL 252 goto auflegen
  29. rem --- Fax ?
  30. IF ERRORLEVEL 251 goto data_anruf
  31. rem --- anderer Fehler oder Abbruch durch Benutzer (alle E.l. >= 15) ?
  32. IF ERRORLEVEL 15 goto auflegen
  33. rem --- Fernabfrage (mit Tonwahl "4") ?
  34. IF ERRORLEVEL 14 goto fernabfrage
  35.  
  36. rem --- Piep erzeugen, Nachricht aufnehmen, max. 30 Sekunden
  37. ZUTIL R /F500 /D1 /T30 *.ZYX
  38.  
  39. rem --- Fehler ?
  40. IF ERRORLEVEL 252 goto auflegen
  41. rem --- evtl. doch ein Fax ?
  42. IF ERRORLEVEL 251 goto data_anruf
  43. rem --- Abbruch durch Benutzer
  44. IF ERRORLEVEL 250 goto auflegen
  45. rem --- Anrufer gibt nichts von sich (vielleicht doch Modem oder Fax ?)
  46. IF ERRORLEVEL 249 goto data_anruf
  47.  
  48. rem --- BZT - zugelassene Anrufbeantworter muessen eine 'Absage' spielen
  49. ZUTIL P /F500 /D1 ZEIT_AUS.ZYX
  50.  
  51. :auflegen
  52. ZUTIL H
  53. GOTO start
  54.  
  55. rem -------------------------------------------
  56.  
  57. :data_anruf
  58.  
  59. rem --- Fax/Datenmodus einschalten
  60. ZUTIL S "AT#B1+FCLASS=6|" "OK" /T2
  61.  
  62. rem --- Fehler
  63. IF ERRORLEVEL 2 GOTO auflegen
  64.  
  65. rem --- Versuchen, einen Connect herzustellen
  66. ZUTIL S "ATA|" "FAX" "2400" "4800" "7200" "9600" "12000" "14400" "16800" "19200" "NO " /T45
  67.  
  68. rem --- "NO CARRIER" vom Modem, Timeout oder allg. Fehler...
  69. IF ERRORLEVEL 10 GOTO auflegen
  70. rem --- Modemconnect ?
  71. IF ERRORLEVEL 2 GOTO mailbox_aufrufen
  72. rem --- nein, also Faxconnect. (folgender Befehl gilt ab ZFAX2.2)
  73. RCVFAX 2
  74. GOTO start
  75.  
  76. :mailbox_aufrufen
  77. rem --- z.B.
  78. TELIX O SHOSTPLUS
  79. GOTO start
  80.  
  81. :fernabfrage
  82. rem --- alle aufgezeichneten nachrichten abspielen
  83. ZUTIL P /F800 /D1 ZUTIL*.ZYX
  84.  
  85. GOTO auflegen
  86.  
  87.  
  88.